locore1.S
12.3 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
/*
* locore.s for ERC32
*
* This program is free software; you can redistribute it and/or modify it under
* the terms of the GNU General Public License as published by the Free
* Software Foundation; either version 2 of the License, or (at your option)
* any later version.
*
* This program is distributed in the hope that it will be useful, but WITHOUT
* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
* FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
* more details.
*
* You should have received a copy of the GNU General Public License along with
* this program; if not, write to the Free Software Foundation, Inc., 675
* Mass Ave, Cambridge, MA 02139, USA.
*
*/
#include "leon.h"
#include "test.h"
/* The traptable has to be the first code in a boot PROM. */
/* Entry for traps which jump to a programmer-specified trap handler. */
#define TRAP(H) mov %psr, %l0; sethi %hi(H), %l4; jmp %l4+%lo(H); mov %tbr, %l3;
#define TRAPL(H) mov %g0, %l0; sethi %hi(H), %l4; jmp %l4+%lo(H); nop;
#define SRMMU_TFAULT(H) rd %psr, %l0; sethi %hi(H), %l4; jmp %l4+%lo(H); mov 1, %l7;
#define SRMMU_DFAULT(H) rd %psr, %l0; sethi %hi(H), %l4; jmp %l4+%lo(H); mov 0, %l7;
/* Unexcpected trap will halt the processor by forcing it to error state */
#define BAD_TRAP ta 0; nop; nop; nop;
/* Software trap. Treat as BAD_TRAP for the time being... */
//#define SOFT_TRAP BAD_TRAP
#define SOFT_TRAP TRAP(soft_trap);
#define PSR_INIT 0x10c0 /* Disable traps, set s and ps */
#define PSR_PS 0x40
#define WIM_INIT 2
#define SP_INIT 0x023ffff0
WINDOWSIZE = (16 * 4)
ARGPUSHSIZE = (6 * 4)
ARGPUSH = (WINDOWSIZE + 4)
MINFRAME = (WINDOWSIZE + ARGPUSHSIZE + 4)
#define STACK_ALIGN 8
#define SA(X) (((X)+(STACK_ALIGN-1)) & ~(STACK_ALIGN-1))
.seg "text"
.global _trap_table, start, _start, _hardreset, test1, fsr1, fq1, fsr1, fq
.global patch_itrap, patch_dtrap, patch_dtrap_replace, patch_itrap_replace, srmmu_fault, _mmu_switch
.global _dexcn, dexcn, _irqtbl, irqtbl, _skip
.global _tmrcnt
/* Hardware traps */
start:
_trap_table:
_hardreset:
TRAPL(_reset); ! 00 reset trap
patch_itrap:
BAD_TRAP; ! 01 instruction_access_exception
TRAP(_skipn); ! 02 illegal_instruction
BAD_TRAP; ! 03 priveleged_instruction
BAD_TRAP; ! 04 fp_disabled
TRAP(_window_overflow); ! 05 window_overflow
TRAP(_window_underflow); ! 06 window_underflow
TRAP(halt); ! 07 memory_address_not_aligned
TRAP(fptrap) ! 08 fp_exception
patch_dtrap:
TRAP(_skipn); ! 09 data_access_exception
BAD_TRAP; ! 0A tag_overflow
TRAP(_skipn); ! 0B watchpoint_exception
BAD_TRAP; ! 0C undefined
BAD_TRAP; ! 0D undefined
BAD_TRAP; ! 0E undefined
BAD_TRAP; ! 0F undefined
BAD_TRAP; ! 10 undefined
/* Interrupt entries */
TRAP(_irqh); ! 11 interrupt level 1
/* TRAP(_reex); ! 11 interrupt level 1 */
TRAP(_irqh); ! 12 interrupt level 2
TRAP(_irqh); ! 13 interrupt level 3
TRAP(_irqh); ! 14 interrupt level 4
TRAP(_irqh); ! 15 interrupt level 5
TRAP(_irqh); ! 16 interrupt level 6
TRAP(_irqh); ! 17 interrupt level 7
TRAP(_timer_irq); ! 18 interrupt level 8 - Timer 1
TRAP(_irqh); ! 19 interrupt level 9
TRAP(_irqh); ! 1A interrupt level 1
TRAP(_irqh); ! 1B interrupt level 11
TRAP(_irqh); ! 1C interrupt level 12
TRAP(_irqh); ! 1D interrupt level 13
TRAP(_irqh); ! 1E interrupt level 14
TRAP(_irqh); ! 1F interrupt level 15
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 20 - 23 undefined
BAD_TRAP; ! 24 cp_disabled
BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 25 - 27 undefined
BAD_TRAP; ! 28 cp_exception
BAD_TRAP; BAD_TRAP; ! 29 - 2A undefined
TRAP(_reexn); ! 2B data_store_error
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 2C - 2F undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 30 - 33 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 34 - 37 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 38 - 3B undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 3C - 3F undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 40 - 43 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 44 - 47 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 48 - 4B undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 4C - 4F undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 50 - 53 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 54 - 57 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 58 - 5B undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 5C - 5F undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 60 - 63 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 64 - 67 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 68 - 6B undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 6C - 6F undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 70 - 73 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 74 - 77 undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 78 - 7B undefined
BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 7C - 7F undefined
/* Software traps */
SOFT_TRAP; SOFT_TRAP; TRAP(spil); ! 80 - 82
TRAP(_flush_windows) ! 83
TRAP(_skip); SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! 84 - 87
TRAP(_entersuper); ! 88 enter supervisor mode
TRAP(_enteruser); ! 89 enter user mode
TRAP(_mmu_switch); ! 8a mmu test: toggle ctx 1|0
SOFT_TRAP; ! 8B
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! 8C - 8F
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! 90 - 93
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! 94 - 97
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! 98 - 9B
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! 9C - 9F
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! A0 - A3
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! A4 - A7
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! A8 - AB
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! AC - AF
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! B0 - B3
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! B4 - B7
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! B8 - BB
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! BC - BF
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! C0 - C3
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! C4 - C7
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! C8 - CB
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! CC - CF
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! D0 - D3
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! D4 - D7
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! D8 - DB
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! DC - DF
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! E0 - E3
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! E4 - E7
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! E8 - EB
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! EC - EF
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! F0 - F3
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! F4 - F7
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! F8 - FB
SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; ! FC - FF
soft_trap:
ta 0
nop
nop
nop
stloop:
b stloop
nop
patch_dtrap_replace:
SRMMU_DFAULT(srmmu_fault)
patch_itrap_replace:
SRMMU_TFAULT(srmmu_fault)
_entersuper: ! ta 8 enter supervisor mode
mov %psr, %l6
or %l6,PSR_PS,%l6
mov %l6, %psr ! set previous supervisor %psr
nop; nop; nop
jmp %l2 ! Jump to nPC
rett %l2 + 4
_enteruser: ! ta 9 enter supervisor mode
mov %psr, %l6
andn %l6,PSR_PS,%l6
mov %l6, %psr ! clear previous supervisor %psr, return to user mode
nop; nop; nop
jmp %l2 ! Jump to nPC
rett %l2 + 4
!
_reset:
! flush ! enable caches
! set PREGS, %g1
! set 0x1000f, %g2
! st %g2, [%g1 + CCTRL] ! initialise registers
! st %g0, [%g1 + IOREG]
! st %g0, [%g1 + IOICONF]
! st %g0, [%g1 + IFORCE]
! st %g0, [%g1 + UCTRL0]
! st %g0, [%g1 + UCTRL1]
! set -1, %g2
! st %g0, [%g1 + ICLEAR]
set _text_start, %g1
mov %g1, %tbr
! set 2, %g2
! mov %g2, %wim
! call _initregs
!
nop
! mov %g3, %sp ! stack pointer
call boot ! call boot routine
nop
_timer_irq:
! - reset pending interrupt
! - update timer counter
! - return to application
set PREGS, %l4
set 0x0100, %l5
st %l5, [%l4 + ICLEAR]
set _tmrcnt, %l4
ld [%l4],%l5
inc %l5
st %l5,[%l4]
jmpl %l1, %g0
rett %l2
nop
nop
_irqh:
! store trap type in irqtbl for later verification
set _irqtbl, %l4
ldub [%l4], %l5
srl %l3, 4, %l3
and %l3, 0x0ff, %l3
stb %l3, [%l4+%l5]
add %l5, 1, %l5
stb %l5, [%l4]
jmpl %l1, %g0
rett %l2
nop
nop
_reex:
jmpl %l1, %g0
rett %l2
nop
nop
fptrap:
set fsr1, %l4
set fq1, %l6
1:
st %fsr, [%l4]
ld [%l4], %l5
srl %l5, 13, %l5
andcc %l5, 1, %l5
bne,a 1b
std %fq, [%l6]
jmpl %l2, %g0
rett %l2 + 4
nop
_skip:
jmpl %l2, %g0
rett %l2 + 4
nop
nop
_skipn:
set _dexcn, %l4
ld [%l4], %l5
subcc %l5, 1, %l5
st %l5, [%l4]
bl dexcfail
nop
jmpl %l2, %g0
rett %l2 + 4
_reexn:
set _dexcn, %l4
ld [%l4], %l5
subcc %l5, 1, %l5
st %l5, [%l4]
bl dexcfail
nop
jmpl %l1, %g0
rett %l2
dexcfail:
ta 0
nop
nop
halt: ta 0
nop
nop
/* Number of register windows */
#define NWINDOWS 8
!Window overflow trap handler.
.global _window_overflow
_window_overflow:
mov %wim, %l3 ! Calculate next WIM
mov %g1, %l7
srl %l3, 1, %g1
sll %l3, NWINDOWS-1 , %l4
or %l4, %g1, %g1
save ! Get into window to be saved.
mov %g1, %wim
nop; nop; nop
st %l0, [%sp + 0];
st %l1, [%sp + 4];
st %l2, [%sp + 8];
st %l3, [%sp + 12];
st %l4, [%sp + 16];
st %l5, [%sp + 20];
st %l6, [%sp + 24];
st %l7, [%sp + 28];
st %i0, [%sp + 32];
st %i1, [%sp + 36];
st %i2, [%sp + 40];
st %i3, [%sp + 44];
st %i4, [%sp + 48];
st %i5, [%sp + 52];
st %i6, [%sp + 56];
st %i7, [%sp + 60];
restore ! Go back to trap window.
mov %l7, %g1
jmp %l1 ! Re-execute save.
rett %l2
/* Window underflow trap handler. */
.global _window_underflow
_window_underflow:
mov %wim, %l3 ! Calculate next WIM
sll %l3, 1, %l4
srl %l3, NWINDOWS-1, %l5
or %l5, %l4, %l5
mov %l5, %wim
nop; nop; nop
restore ! Two restores to get into the
restore ! window to restore
ld [%sp + 0], %l0; ! Restore window from the stack
ld [%sp + 4], %l1;
ld [%sp + 8], %l2;
ld [%sp + 12], %l3;
ld [%sp + 16], %l4;
ld [%sp + 20], %l5;
ld [%sp + 24], %l6;
ld [%sp + 28], %l7;
ld [%sp + 32], %i0;
ld [%sp + 36], %i1;
ld [%sp + 40], %i2;
ld [%sp + 44], %i3;
ld [%sp + 48], %i4;
ld [%sp + 52], %i5;
ld [%sp + 56], %i6;
ld [%sp + 60], %i7;
save ! Get back to the trap window.
save
jmp %l1 ! Re-execute restore.
rett %l2
.global _flush_windows
_flush_windows:
mov %psr, %g1
or %g1, 0x0f00, %g2
restore ! enter previous frame (cannot trap)
wr %g2, 0x20, %psr ! enable traps, disable interrupts
nop; nop; nop
save ! 6 save to flush all windows
save
save
save
save
save
restore ! 5 restore to enter trapped frame
restore
restore
restore
restore
mov %g1, %psr ! restore %psr
nop; nop; nop
jmp %l2 ! Jump to nPC
rett %l2 + 4
.text
.align 4
.global _initregs
.proc 04
_initregs:
mov %g0, %g1
mov %o7, %g2
! mov %g0, %g3
mov %g0, %g4
mov %g0, %g5
mov %g0, %g6
mov %g0, %g7
mov %wim, %g7
mov %g0, %wim
nop; nop; nop
1:
mov %g0, %l0
mov %g0, %l1
mov %g0, %l2
mov %g0, %l3
mov %g0, %l4
mov %g0, %l5
mov %g0, %l6
mov %g0, %l7
mov %g0, %o0
mov %g0, %o1
mov %g0, %o2
mov %g0, %o3
mov %g0, %o4
mov %g0, %o5
mov %g0, %o6
mov %g0, %o7
save
subcc %g1, 7, %g0
bne 1b
inc %g1
mov %g7, %wim
nop
nop
nop
mov %g2, %o7
retl
nop
.global _setpil
_setpil:
retl
ta 2
spil:
mov %psr, %l4
srl %l4, 8, %l5
andn %l4, 0x0f00, %l4
sll %i0, 8, %i0
and %i0, 0x0f00, %i0
or %i0, %l4, %l4
mov %l4, %psr
and %l5, 0x0f, %i0
jmpl %l2, %g0
rett %l2 + 4
hello:
.string "Starting test"
.align 4
_dexcn:
dexcn:
.word 0
.data
_irqtbl:
irqtbl:
.word 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
_tmrcnt:
.word 0
fsr1:
.word 0
fq1:
.word 0